Functions and Variables for draw (Maxima Manual)

42.2 Functions and Variables for draw

Scenes
Functions
Graphics options
Graphics objects

42.2.1 Scenes

Scene constructor: gr2d (graphic option, …, graphic object, …) ¶

Function gr2d builds an object describing a 2D scene. Arguments are graphic options, graphic objects, or lists containing both graphic options and objects. This scene is interpreted sequentially: graphic options affect those graphic objects placed on its right. Some graphic options affect the global appearence of the scene.

This is the list of graphic objects available for scenes in two dimensions:

bars, ellipse, explicit, image, implicit, label, parametric, points, polar, polygon, quadrilateral, rectangle, triangle, vector, and geomap (this one defined in package worldmap).

See also draw and draw2d. To make use of this object, write first load("draw").

Scene constructor: gr3d (graphic option, …, graphic object, …) ¶

Function gr3d builds an object describing a 3d scene. Arguments are graphic options, graphic objects, or lists containing both graphic options and objects. This scene is interpreted sequentially: graphic options affect those graphic objects placed on its right. Some graphic options affect the global appearence of the scene.

This is the list of graphic objects available for scenes in three dimensions:

cylindrical, elevation_grid, explicit, implicit, label, mesh, parametric, parametric_surface, points, quadrilateral, spherical, triangle, tube, vector, and geomap (this one defined in package worldmap).

See also draw and draw3d. To make use of this object, write first load("draw").

42.2.2 Functions

Function: draw (gr2d, …, gr3d, …, options, …) ¶

Plots a series of scenes; its arguments are gr2d and/or gr3d objects, together with some options, or lists of scenes and options. By default, the scenes are put together in one column.

Function draw accepts the following global options: terminal, columns, dimensions, file_name and delay.

Functions draw2d and draw3d are short cuts to be used when only one scene is required, in two or three dimensions, respectively.

See also gr2d and gr3d. To make use of this function, write first load("draw").

Example:

(%i1) load("draw")$
(%i2) scene1: gr2d(title="Ellipse",
                   nticks=30,
                   parametric(2*cos(t),5*sin(t),t,0,2*%pi))$
(%i3) scene2: gr2d(title="Triangle",
                   polygon([4,5,7],[6,4,2]))$
(%i4) draw(scene1, scene2, columns = 2)$

The two draw sentences are equivalent:

(%i1) load("draw")$
(%i2) draw(gr3d(explicit(x^2+y^2,x,-1,1,y,-1,1)));
(%o2)                          [gr3d(explicit)]
(%i3) draw3d(explicit(x^2+y^2,x,-1,1,y,-1,1));
(%o3)                          [gr3d(explicit)]

An animated gif file:

(%i1) load("draw")$
(%i2) draw(
        delay     = 100,
        file_name = "zzz",
        terminal  = 'animated_gif,
        gr2d(explicit(x^2,x,-1,1)),
        gr2d(explicit(x^3,x,-1,1)),
        gr2d(explicit(x^4,x,-1,1)));
End of animation sequence
(%o2)          [gr2d(explicit), gr2d(explicit), gr2d(explicit)]

See also gr2d, gr3d, draw2d and draw3d.

Function: draw2d (option, graphic_object, …) ¶

This function is a short cut for draw(gr2d(options, ..., graphic_object, ...)).

It can be used to plot a unique scene in 2d.

To make use of this function, write first load("draw").

42.2.3 Graphics options

Graphic option: adapt_depth ¶

Default value: 10

adapt_depth is the maximum number of splittings used by the adaptive plotting routine.

This option is relevant only for 2d explicit functions.

Graphic option: axis_3d ¶

Default value: true

If axis_3d is true, the x, y and z axis are shown in 3d scenes.

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load("draw")$
(%i2) draw3d(axis_3d = false,
             explicit(sin(x^2+y^2),x,-2,2,y,-2,2) )$

See also axis_bottom, axis_left, axis_top, and axis_right for axis in 2d.

Graphic option: axis_bottom ¶

Default value: true

If axis_bottom is true, the bottom axis is shown in 2d scenes.

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load("draw")$
(%i2) draw2d(axis_bottom = false,
             explicit(x^3,x,-1,1))$

See also axis_left, axis_top, axis_right, and axis_3d.

Graphic option: axis_left ¶

Default value: true

If axis_left is true, the left axis is shown in 2d scenes.

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load("draw")$
(%i2) draw2d(axis_left = false,
             explicit(x^3,x,-1,1))$

See also axis_bottom, axis_top, axis_right, and axis_3d.

Graphic option: axis_right ¶

Default value: true

If axis_right is true, the right axis is shown in 2d scenes.

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load("draw")$
(%i2) draw2d(axis_right = false,
             explicit(x^3,x,-1,1))$

See also axis_bottom, axis_left, axis_top, and axis_3d.

Graphic option: axis_top ¶

Default value: true

If axis_top is true, the top axis is shown in 2d scenes.

Since this is a global graphics option, its position in the scene description does not matter.

Example:

(%i1) load("draw")$
(%i2) draw2d(axis_top = false,
             explicit(x^3,x,-1,1))$

See also axis_bottom, axis_left, axis_right, and axis_3d.

Graphic option: background_color ¶

Default value: white

Sets the background color for terminals gif, png, jpg, and gif. Default background color is white.

This option das not work with terminals epslatex and epslatex_standalone.

42.2.4 Graphics objects

Graphic object: bars ([x1, h1, w1], [x2, h2, w2, …]) ¶

Draws vertical bars in 2D.

bars([x1, h1, w1], [x2, h2, w2, ...]) draws bars centered at values x1, x2, … with heights h1, h2, … and widths w1, w2, …

This object is affected by the following graphic options: key, fill_color, fill_density and line_width.

Example:

(%i1) load("draw")$
(%i2) draw2d(
       key          = "Group A",
       fill_color   = blue,
       fill_density = 0.2,
       bars([0.8,5,0.4],[1.8,7,0.4],[2.8,-4,0.4]),
       key          = "Group B",
       fill_color   = red,
       fill_density = 0.6,
       line_width   = 4,
       bars([1.2,4,0.4],[2.2,-2,0.4],[3.2,5,0.4]),
       xaxis = true);

Graphic object: cylindrical (radius, z, minz, maxz, azi, minazi, maxazi) ¶

Draws 3D functions defined in cylindrical coordinates.

cylindrical(radius, z, minz, maxz, azi, minazi, maxazi) plots function radius(z, azi) defined in cylindrical coordinates, with variable z taking values from minz to maxz and azimuth azi taking values from minazi to maxazi.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, key, wired_surface, enhanced3d and color.

Example:

(%i1) load("draw")$
(%i2) draw3d(cylindrical(1,z,-2,2,az,0,2*%pi))$

Graphic object: elevation_grid (mat, x0, y0, width, height) ¶

Draws matrix mat in 3D space. z values are taken from mat, the abscissas range from x0 to x0 + width and ordinates from y0 to y0 + height. Element \(a(1,1)\) is projected on point \((x0,y0+height)\), \(a(1,n)\) on \((x0+width,y0+height)\), \(a(m,1)\) on \((x0,y0)\), and \(a(m,n)\) on \((x0+width,y0)\).

This object is affected by the following graphic options: line_type, line_width, key, wired_surface, enhanced3d, and color.

In older versions of Maxima, elevation_grid was called mesh. See also mesh.

Example:

(%i1) load("draw")$
(%i2) m: apply(
            matrix,
            makelist(makelist(random(10.0),k,1,30),i,1,20)) $
(%i3) draw3d(
         color = blue,
         elevation_grid(m,0,0,3,2),
         xlabel = "x",
         ylabel = "y",
         surface_hide = true);

Graphic object: ellipse (xc, yc, a, b, ang1, ang2) ¶

Draws ellipses and circles in 2D.

ellipse (xc, yc, a, b, ang1, ang2) plots an ellipse centered at [xc, yc] with horizontal and vertical semi axis a and b, respectively, starting at angle ang1 with an amplitude equal to angle ang2.

This object is affected by the following graphic options: nticks, transparent, fill_color, border, line_width, line_type, key and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(transparent = false,
             fill_color  = red,
             color       = gray30,
             transparent = false,
             line_width  = 5,
             ellipse(0,6,3,2,270,-270),
             /* center (x,y), a, b, start & end in degrees */
             transparent = true,
             color       = blue,
             line_width  = 3,
             ellipse(2.5,6,2,3,30,-90),
             xrange      = [-3,6],
             yrange      = [2,9] )$

Graphic object: errors ([x1, x2, …], [y1, y2, …]) ¶

Draws points with error bars, horizontally, vertically or both, depending on the value of option error_type.

If error_type = x, arguments to errors must be of the form [x, y, xdelta] or [x, y, xlow, xhigh]. If error_type = y, arguments must be of the form [x, y, ydelta] or [x, y, ylow, yhigh]. If error_type = xy or error_type = boxes, arguments to errors must be of the form [x, y, xdelta, ydelta] or [x, y, xlow, xhigh, ylow, yhigh].

See also colorbox.

If im is a matrix of vectors of length three, they are interpreted as red, green and blue color components.

(%i1) load("draw")$
(%i2) im: apply(
            'matrix,
             makelist(
               makelist([random(300),
                         random(300),
                         random(300)],i,1,30),i,1,30))$
(%i3) draw2d(image(im,0,0,30,30))$

Package draw automatically loads package picture. In this example, a level picture object is built by hand and then rendered.

(%i1) load("draw")$
(%i2) im: make_level_picture([45,87,2,134,204,16],3,2);
(%o2)       picture(level, 3, 2, {Array:  #(45 87 2 134 204 16)})
(%i3) /* default color palette */
      draw2d(image(im,0,0,30,30))$
(%i4) /* gray palette */
      draw2d(palette = gray,
             image(im,0,0,30,30))$

An xpm file is read and then rendered.

(%i1) load("draw")$
(%i2) im: read_xpm("myfile.xpm")$
(%i3) draw2d(image(im,0,0,10,7))$

See also make_level_picture, make_rgb_picture and read_xpm.

http://www.telefonica.net/web2/biomates/maxima/gpdraw/image contains more elaborated examples.

Graphic object: implicit (fcn, x, xmin, xmax, y, ymin, ymax) ¶

Graphic object: implicit (fcn, x, xmin, xmax, y, ymin, ymax, z, zmin, zmax) ¶

Draws implicit functions in 2D and 3D.

implicit(fcn, x, xmin, xmax, y, ymin, ymax) plots the implicit function defined by fcn, with variable x taking values from xmin to xmax, and variable y taking values from ymin to ymax.

This object is affected by the following graphic options: ip_grid, ip_grid_in, line_width, line_type, key and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(terminal  = eps,
             grid      = true,
             line_type = solid,
             key       = "y^2=x^3-2*x+1",
             implicit(y^2=x^3-2*x+1, x, -4,4, y, -4,4),
             line_type = dots,
             key       = "x^3+y^3 = 3*x*y^2-x-1",
             implicit(x^3+y^3 = 3*x*y^2-x-1, x,-4,4, y,-4,4),
             title     = "Two implicit functions" )$

implicit(fcn, x, xmin, xmax, y, ymin, ymax, z, zmin, zmax) plots the implicit surface defined by fcn, with variable x taking values from xmin to xmax, variable y taking values from ymin to ymax and variable z taking values from zmin to zmax. This object implements the marching cubes algorithm.

This object is affected by the following graphic options: x_voxel, y_voxel, z_voxel, line_width, line_type, key, wired_surface, enhanced3d, and color.

Example:

(%i1) load("draw")$
(%i2) draw3d(
        color=blue,
        implicit((x^2+y^2+z^2-1)*(x^2+(y-1.5)^2+z^2-0.5)=0.015,
                 x,-1,1,y,-1.2,2.3,z,-1,1),
        surface_hide=true);

Graphic object: label ([string, x, y], …) ¶

Graphic object: label ([string, x, y, z], …) ¶

Writes labels in 2D and 3D.

Colored labels work only with Gnuplot 4.3. This is a known bug in package draw.

This object is affected by the following graphic options: label_alignment, label_orientation and color.

label([string, x, y]) writes the string at point [x, y].

Example:

(%i1) load("draw")$
(%i2) draw2d(yrange = [0.1,1.4],
             color = red,
             label(["Label in red",0,0.3]),
             color = "#0000ff",
             label(["Label in blue",0,0.6]),
             color = light_blue,
             label(["Label in light-blue",0,0.9],
                   ["Another light-blue",0,1.2])  )$

label([string, x, y, z]) writes the string at point [x, y, z].

Example:

(%i1) load("draw")$
(%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3),
             color = red,
             label(["UP 1",-2,0,3], ["UP 2",1.5,0,4]),
             color = blue,
             label(["DOWN 1",2,0,-3]) )$

Graphic object: mesh (row_1, row_2, …) ¶

Draws a quadrangular mesh in 3D.

Argument row_i is a list of n 3D points of the form [[x_i1,y_i1,z_i1], ...,[x_in,y_in,z_in]], and all rows are of equal length. All these points define an arbitrary surface in 3D and in some sense it’s a generalization of the elevation_grid object.

This object is affected by the following graphic options: line_type, line_width, color, key, wired_surface, enhanced3d, and transform.

Examples:

A simple example.

(%i1) load("draw")$
(%i2) draw3d( 
         mesh([[1,1,3],   [7,3,1],[12,-2,4],[15,0,5]],
              [[2,7,8],   [4,3,1],[10,5,8], [12,7,1]],
              [[-2,11,10],[6,9,5],[6,15,1], [20,15,2]])) $

Plotting a triangle in 3D.

(%i1) load("draw")$
(%i2) draw3d(
        line_width = 2,
        mesh([[1,0,0],[0,1,0]],
             [[0,0,1],[0,0,1]])) $

Two quadrilaterals.

(%i1) load("draw")$
(%i2) draw3d(
        surface_hide = true,
        line_width   = 3,
        color = red,
        mesh([[0,0,0], [0,1,0]],
             [[2,0,2], [2,2,2]]),
        color = blue,
        mesh([[0,0,2], [0,1,2]],
             [[2,0,4], [2,2,4]])) $

Graphic object: parametric (xfun, yfun, par, parmin, parmax) ¶

Graphic object: parametric (xfun, yfun, zfun, par, parmin, parmax) ¶

Draws parametric functions in 2D and 3D.

This object is affected by the following graphic options: nticks, line_width, line_type, key, color and enhanced3d.

parametric(xfun, yfun, par, parmin, parmax) plots the parametric function [xfun, yfun], with the parameter par taking values from parmin to parmax.

Example:

(%i1) load("draw")$
(%i2) draw2d(explicit(exp(x),x,-1,3),
             color = red,
             key   = "This is the parametric one!!",
             parametric(2*cos(rrr),rrr^2,rrr,0,2*%pi))$

The command parametric(xfun, yfun, zfun, par, parmin, parmax) plots the parametric curve [xfun, yfun, zfun], with the parameter par taking values from parmin to parmax.

Example:

(%i1) load("draw")$
(%i2) draw3d(explicit(exp(sin(x)+cos(x^2)),x,-3,3,y,-3,3),
             color = royalblue,
             parametric(cos(5*u)^2,sin(7*u),u-2,u,0,2),
             color      = turquoise,
             line_width = 2,
             parametric(t^2,sin(t),2+t,t,0,2),
             surface_hide = true,
             title = "Surface & curves" )$

Graphic object: parametric_surface (xfun, yfun, zfun, par1, par1min, par1max, par2, par2min, par2max) ¶

Draws parametric surfaces in 3D.

parametric_surface(xfun, yfun, zfun, par1, par1min, par1max, par2, par2min, par2max) plots the parametric surface [xfun, yfun, zfun], with the parameter par1 taking values from par1min to par1max and the parameter par2 taking values from par2min to par2max.

This object is affected by the following graphic options: draw_realpart, xu_grid, yv_grid, line_type, line_width, key, wired_surface, enhanced3d, and color.

Example:

(%i1) load("draw")$
(%i2) draw3d(title          = "Sea shell",
             xu_grid        = 100,
             yv_grid        = 25,
             view           = [100,20],
             surface_hide   = true,
             parametric_surface(0.5*u*cos(u)*(cos(v)+1),
                           0.5*u*sin(u)*(cos(v)+1),
                           u*sin(v) - ((u+3)/8*%pi)^2 - 20,
                           u, 0, 13*%pi, v, -%pi, %pi) )$

Graphic object: points ([[x1, y1], [x2, y2], …]) ¶

Graphic object: points ([x1, x2, …], [y1, y2, …]) ¶

Graphic object: points ([y1, y2, …]) ¶

Graphic object: points ([[x1, y1, z1], [x2, y2, z2], …]) ¶

Graphic object: points ([x1, x2, …], [y1, y2, …], [z1, z2, …]) ¶

Graphic object: points (matrix) ¶

Graphic object: points (1d_y_array) ¶

Graphic object: points (1d_x_array, 1d_y_array) ¶

Graphic object: points (1d_x_array, 1d_y_array, 1d_z_array) ¶

Graphic object: points (2d_xy_array) ¶

Graphic object: points (2d_xyz_array) ¶

Draws points in 2D and 3D.

This object is affected by the following graphic options: point_size, point_type, points_joined, line_width, key, line_type and color. In 3D mode, it is also affected by enhanced3d.

points([[x1, y1], [x2, y2], ...]) or points([x1, x2, ...], [y1, y2, ...]) plots points [x1, y1], [x2, y2], etc. If abscissas are not given, they are set to consecutive positive integers, so that points([y1, y2, ...]) draws points [1, y1], [2, y2], etc. If matrix is a two-column or two-row matrix, points (matrix) draws the associated points. If matrix is a one-column or one-row matrix, abscissas are assigned automatically.

If 1d_y_array is a 1D lisp array of numbers, points(1d_y_array) plots them setting abscissas to consecutive positive integers. points(1d_x_array, 1d_y_array) plots points with their coordinates taken from the two arrays passed as arguments. If 2d_xy_array is a 2D array with two columns, or with two rows, points(2d_xy_array) plots the corresponding points on the plane.

Examples:

Two types of arguments for points, a list of pairs and two lists of separate coordinates.

(%i1) load("draw")$
(%i2) draw2d(
        key = "Small points",
        points(makelist([random(20),random(50)],k,1,10)),
        point_type    = circle,
        point_size    = 3,
        points_joined = true,
        key           = "Great points",
        points(makelist(k,k,1,20),makelist(random(30),k,1,20)),
        point_type    = filled_down_triangle,
        key           = "Automatic abscissas",
        color         = red,
        points([2,12,8]))$

Drawing impulses.

(%i1) load("draw")$
(%i2) draw2d(
        points_joined = impulses,
        line_width    = 2,
        color         = red,
        points(makelist([random(20),random(50)],k,1,10)))$

Array with ordinates.

(%i1) load("draw")$
(%i2) a: make_array (flonum, 100) $
(%i3) for i:0 thru 99 do a[i]: random(1.0) $
(%i4) draw2d(points(a)) $

Two arrays with separate coordinates.

(%i1) load("draw")$
(%i2) x: make_array (flonum, 100) $
(%i3) y: make_array (fixnum, 100) $
(%i4) for i:0 thru 99 do (
        x[i]: float(i/100),
        y[i]: random(10) ) $
(%i5) draw2d(points(x, y)) $

A two-column 2D array.

(%i1) load("draw")$
(%i2) xy: make_array(flonum, 100, 2) $
(%i3) for i:0 thru 99 do (
        xy[i, 0]: float(i/100),
        xy[i, 1]: random(10) ) $
(%i4) draw2d(points(xy)) $

Drawing an array filled with function read_array.

(%i1) load("draw")$
(%i2) a: make_array(flonum,100) $
(%i3) read_array (file_search ("pidigits.data"), a) $
(%i4) draw2d(points(a)) $

points([[x1, y1, z1], [x2, y2, z2], ...]) or
points([x1, x2, ...], [y1, y2, ...], [z1, z2, ...]) plots points [x1, y1, z1], [x2, y2, z2], etc. If matrix is a three-column or three-row matrix, points (matrix) draws the associated points.

When arguments are lisp arrays, points(1d_x_array, 1d_y_array, 1d_z_array) takes coordinates from the three 1D arrays. If 2d_xyz_array is a 2D array with three columns, or with three rows, points(2d_xyz_array) plots the corresponding points.

Examples:

One tridimensional sample,

(%i1) load("draw")$
(%i2) load ("numericalio")$
(%i3) s2 : read_matrix (file_search ("wind.data"))$
(%i4) draw3d(title = "Daily average wind speeds",
             point_size = 2,
             points(args(submatrix (s2, 4, 5))) )$

Two tridimensional samples,

(%i1) load("draw")$
(%i2) load ("numericalio")$
(%i3) s2 : read_matrix (file_search ("wind.data"))$
(%i4) draw3d(
         title = "Daily average wind speeds. Two data sets",
         point_size = 2,
         key        = "Sample from stations 1, 2 and 3",
         points(args(submatrix (s2, 4, 5))),
         point_type = 4,
         key        = "Sample from stations 1, 4 and 5",
         points(args(submatrix (s2, 2, 3))) )$

Unidimensional arrays,

(%i1) load("draw")$
(%i2) x: make_array (fixnum, 10) $
(%i3) y: make_array (fixnum, 10) $
(%i4) z: make_array (fixnum, 10) $
(%i5) for i:0 thru 9 do (
        x[i]: random(10),
        y[i]: random(10),
        z[i]: random(10) ) $
(%i6) draw3d(points(x,y,z)) $

Bidimensional colored array,

(%i1) load("draw")$
(%i2) xyz: make_array(fixnum, 10, 3) $
(%i3) for i:0 thru 9 do (
        xyz[i, 0]: random(10),
        xyz[i, 1]: random(10),
        xyz[i, 2]: random(10) ) $
(%i4) draw3d(
         enhanced3d = true,
         points_joined = true,
         points(xyz)) $

Color numbers explicitly specified by the user.

(%i1) load("draw")$
(%i2) pts: makelist([t,t^2,cos(t)], t, 0, 15)$
(%i3) col_num: makelist(k, k, 1, length(pts))$
(%i4) draw3d(
        enhanced3d = ['part(col_num,k),k],
        point_size = 3,
        point_type = filled_circle,
        points(pts))$

Graphic object: polar (radius, ang, minang, maxang) ¶

Draws 2D functions defined in polar coordinates.

polar(radius, ang, minang, maxang) plots function radius(ang) defined in polar coordinates, with variable ang taking values from minang to maxang.

This object is affected by the following graphic options: nticks, line_width, line_type, key and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(user_preamble = "set grid polar",
             nticks        = 200,
             xrange        = [-5,5],
             yrange        = [-5,5],
             color         = blue,
             line_width    = 3,
             title         = "Hyperbolic Spiral",
             polar(10/theta,theta,1,10*%pi) )$

Graphic object: polygon ([[x1, y1], [x2, y2], …]) ¶

Graphic object: polygon ([x1, x2, …], [y1, y2, …]) ¶

Draws polygons in 2D.

polygon([[x1, y1], [x2, y2], ...]) or
polygon([x1, x2, …], [y1,y2, …]): plots on the plane a polygon with vertices [x1, y1], [x2, y2], etc.

This object is affected by the following graphic options: transparent, fill_color, border, line_width, key, line_type and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(color      = "#e245f0",
             line_width = 8,
             polygon([[3,2],[7,2],[5,5]]),
             border      = false,
             fill_color  = yellow,
             polygon([[5,2],[9,2],[7,5]]) )$

Graphic object: quadrilateral (point_1, point_2, point_3, point_4) ¶

Draws a quadrilateral.

quadrilateral([x1, y1], [x2, y2], [x3, y3], [x4, y4]) draws a quadrilateral with vertices [x1, y1], [x2, y2], [x3, y3], and [x4, y4].

This object is affected by the following graphic options:

transparent, fill_color, border, line_width, key, xaxis_secondary, yaxis_secondary, line_type, transform and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(
        quadrilateral([1,1],[2,2],[3,-1],[2,-2]))$

quadrilateral ([x1, y1, z1], [x2, y2, z2], [x3, y3, z3], [x4, y4, z4])
draws a quadrilateral with vertices [x1, y1, z1], [x2, y2, z2], [x3, y3, z3], and [x4, y4, z4].

This object is affected by the following graphic options: line_type, line_width, color, key, enhanced3d, and transform.

Graphic object: rectangle ([x1, y1], [x2, y2]) ¶

Draws rectangles in 2D.

rectangle([x1, y1], [x2, y2]) draws a rectangle with opposite vertices [x1, y1] and [x2, y2].

This object is affected by the following graphic options: transparent, fill_color, border, line_width, key, line_type and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(fill_color  = red,
             line_width  = 6,
             line_type   = dots,
             transparent = false,
             fill_color  = blue,
             rectangle([-2,-2],[8,-1]), /* opposite vertices */
             transparent = true,
             line_type   = solid,
             line_width  = 1,
             rectangle([9,4],[2,-1.5]),
             xrange      = [-3,10],
             yrange      = [-3,4.5] )$

Graphic object: region (expr, var1, minval1, maxval1, var2, minval2, maxval2) ¶

Plots a region on the plane defined by inequalities.

2D expr is an expression formed by inequalities and boolean operators and, or, and not. The region is bounded by the rectangle defined by [minval1, maxval1] and [minval2, maxval2].

This object is affected by the following graphic options: fill_color, key, x_voxel, and y_voxel.

Example:

(%i1) load("draw")$
(%i2) draw2d(
        x_voxel = 30,
        y_voxel = 30,
        region(x^2+y^2<1 and x^2+y^2 > 1/2,
               x, -1.5, 1.5, y, -1.5, 1.5));

Graphic object: spherical (radius, azi, minazi, maxazi, zen, minzen, maxzen) ¶

Draws 3D functions defined in spherical coordinates.

spherical(radius, azi, minazi, maxazi, zen, minzen, maxzen) plots function radius(azi, zen) defined in spherical coordinates, with azimuth azi taking values from minazi to maxazi and zenith zen taking values from minzen to maxzen.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, key, wired_surface, enhanced3d, and color.

Example:

(%i1) load("draw")$
(%i2) draw3d(spherical(1,a,0,2*%pi,z,0,%pi))$

Graphic object: triangle (point_1, point_2, point_3) ¶

Draws a triangle.

triangle([x1, y1], [x2, y2], [x3, y3]) draws a triangle with vertices [x1, y1], [x2, y2], and [x3,y3].

This object is affected by the following graphic options:

transparent, fill_color, border, line_width, key, xaxis_secondary, yaxis_secondary, line_type, transform, and color.

Example:

(%i1) load("draw")$
(%i2) draw2d(
        triangle([1,1],[2,2],[3,-1]))$

triangle([x1, y1, z1], [x2, y2, z2], [x3, y3, z3]) draws a triangle with vertices [x1, y1, z1], [x2, y2, z2], and [x3, y3, z3].

This object is affected by the following graphic options: line_type, line_width, color, key, enhanced3d, and transform.

Graphic object: tube (xfun, yfun, zfun, rfun, p, pmin, pmax) ¶

Draws a tube in 3D with varying diameter.

[xfun,yfun,zfun] is the parametric curve with parameter p taking values from pmin to pmax. Circles of radius rfun are placed with their centers on the parametric curve and perpendicular to it.

This object is affected by the following graphic options: xu_grid, yv_grid, line_type, line_width, key, wired_surface, enhanced3d, color, and tube_extremes.

Example:

(%i1) load("draw")$
(%i2) draw3d(
        enhanced3d = true,
        xu_grid = 50,
        tube(cos(a), a, 0, cos(a/10)^2,
             a, 0, 4*%pi) )$

Graphic object: vector ([x, y], [dx, dy]) ¶

Graphic object: vector ([x, y, z], [dx, dy, dz]) ¶

Draws vectors in 2D and 3D.

This object is affected by the following graphic options: head_both, head_length, head_angle, head_type, line_width, line_type, key and color.

vector([x, y], [dx,dy]) plots vector [dx, dy] with origin in [x, y].

Example:

(%i1) load("draw")$
(%i2) draw2d(xrange      = [0,12],
             yrange      = [0,10],
             head_length = 1,
             vector([0,1],[5,5]), /* default type */
             head_type = 'empty,
             vector([3,1],[5,5]),
             head_both = true,
             head_type = 'nofilled,
             line_type = dots,
             vector([6,1],[5,5]))$

vector([x, y, z], [dx, dy, dz]) plots vector [dx,dy,dz] with origin in [x, y, z].

Example:

(%i1) load("draw")$
(%i2) draw3d(color = cyan,
             vector([0,0,0],[1,1,1]/sqrt(3)),
             vector([0,0,0],[1,-1,0]/sqrt(2)),
             vector([0,0,0],[1,1,-2]/sqrt(6)) )$