74.2 Funciones y variables para inference_result

Función: inference_result (title, values, numbers) ¶

Construye un objeto inference_result del tipo devuelto por las funciones estadísticas. El argumento title es una cadena con el nombre del procedimiento; values es una lista con elementos de la forma symbol = value y numbers es una lista con enteros positivos desde uno hasta length(values), que indican qué valores serán mostrados por defecto.

Ejemplo:

Este es un ejemplo que muestra los resultados asociados a un rectángulo. El título de este objeto es la cadena "Rectangle", el cual almacena cinco resultados, a saber, 'base, 'height, 'diagonal, 'area y 'perimeter, pero sólo muestra el primero, segundo, quinto y cuarto. El resultado 'diagonal también se almacena en este objeto, pero no se muestra por defecto; para tener acceso a este valor, hágase uso de la función take_inference.

(%i1) load("inference_result")$
(%i2) b: 3$ h: 2$
(%i3) inference_result("Rectangle",
                        ['base=b,
                         'height=h,
                         'diagonal=sqrt(b^2+h^2),
                         'area=b*h,
                         'perimeter=2*(b+h)],
                        [1,2,5,4] );
                        |   Rectangle
                        |
                        |    base = 3
                        |
(%o3)                   |   height = 2
                        |
                        | perimeter = 10
                        |
                        |    area = 6
(%i4) take_inference('diagonal,%);
(%o4)                        sqrt(13)

Véase también take_inference.

Función: inferencep (obj) ¶

Devuelve true o false, dependiendo de que obj sea un objeto de tipo inference_result o no.

Función: items_inference (obj) ¶

Devuelve una lista con los nombres de los elementos almacenados en obj, el cual debe ser un objeto de tipo inference_result.

Ejemplo:

El objeto inference_result almacena dos valores, cuyos nombres son 'pi y 'e, pero sólo se muestra el segundo. La función items_inference devuelve los nombres de todos los elementos almacenados, independientemente de que sean mostrados o no.

(%i1) load("inference_result")$
(%i2) inference_result("Hi", ['pi=%pi,'e=%e],[2]);
                            |   Hi
(%o2)                       |
                            | e = %e
(%i3) items_inference(%);
(%o3)                        [pi, e]

Función: take_inference (n, obj) ¶

Función: take_inference (name, obj) ¶

Función: take_inference (list, obj) ¶

Si n es un entero positivo, devuelve el n-ésimo valor almacenado en obj; si el símbolo name es el nombre de uno de los elementos almacenados, también devuelve su valor. Si el primer elemento es una lista de números y/o símbolos, la función take_inference devuelve una lista con los resultados correspondientes.

Ejemplo:

Dado un objeto inference_result, la función take_inference es invocada para extraer cierta información almacenada en él.

(%i1) load("inference_result")$
(%i2) b: 3$ h: 2$
(%i3) sol: inference_result("Rectangle",
                            ['base=b,
                             'height=h,
                             'diagonal=sqrt(b^2+h^2),
                             'area=b*h,
                             'perimeter=2*(b+h)],
                            [1,2,5,4] );
                        |   Rectangle
                        |
                        |    base = 3
                        |
(%o3)                   |   height = 2
                        |
                        | perimeter = 10
                        |
                        |    area = 6
(%i4) take_inference('base,sol);
(%o4)                           3
(%i5) take_inference(5,sol);
(%o5)                          10
(%i6) take_inference([1,'diagonal],sol);
(%o6)                     [3, sqrt(13)]
(%i7) take_inference(items_inference(sol),sol);
(%o7)                [3, 2, sqrt(13), 6, 10]

Véanse también inference_result y take_inference.