|
|
|
Essa seção usa material do livro de Alfred Gray:
Modern Differential Geometry of Curves and Surfaces,
1994 CRC Press, Florida
A representação paramétrica de uma curva plana pode ser escrita como um vetor em duas dimensãoes. Os elementos desse vetor são funções do parâmetro t:
alfa(t) := [sin(t), cos(t)];
Obetemos a definição como resposta:
alfa(t) := [sin(t), cos(t)]
Podemos calcular a derivação:
diff(alfa(z), z);
E recebemos esse resultado:
[cos(z), - sin(z)]
A seguir, definimos uma função, que é chamada "estrutura complexa":
J(a) := [-a[2], a[1]];
J(a) := [- a , a ]
2 1
Na definição de J, assumimos que a é um vetor com exatamente dois elementos. Isso não foi dclarado nem verificado.
Aqui está como isso funciona:
J(alfa(y));
[- cos(y), sin(y)]
Em interpretação geométrica, isso é uma rotação de 90 graus. Não é surpresa que o produto escalar de alpha(z) e J(alpha(z)) seja zero:
alfa(z).J(alfa(z));
0
Agora definimos a curvatura de uma curva plana
kapa(fn, t) := diff(fn(t), t, 2).J(diff(fn(t), t))/((diff(fn(t), t).diff(fn(t), t))^(3/2));
diff(fn(t), t, 2) . j(diff(fn(t), t))
kapa(fn, t) := -------------------------------------
3/2
(diff(fn(t), t) . diff(fn(t), t))
Agora vamos calcular a curvatura de alpha:
kapa(alfa, t);
Maxima responde:
2 2
- sin (t) - cos (t)
----------------------
2 2 3/2
(sin (t) + cos (t))
Isso é um resultado surpreendentemente complicado: alfa(t) é uma representação paramétrica de um círculo e um círculo pode ter curvatura constante. Uma tentativa de simplificar esse resultado é certamente proveitoso:
trigsimp(%);
Agora Maxima confirma o que pensávamos: um círculo tem curvatura constante.
- 1
Agora, vamos examinar uma curva um pouco mais complicada, a curva em forma de oito:
oito(t) := [sin(t), sin(t)*cos(t)];
oito(t) := [sin(t), sin(t) cos(t)]
Para desenhar aquela curva, podemos usar esse comando:
plot2d(append('[parametric], oito (t), [[t, -%pi, %pi]], [[nticks, 360]]));
O diagrama é mostrado em uma janela separada.
Agora podemos calcular a curvatura:
kapa(oito, z);
e obtemos:
2 2 2
- sin(z) (sin (z) - cos (z)) - 4 cos (z) sin(z)
-----------------------------------------------
2 2 2 2 3/2
((cos (z) - sin (z)) + cos (z))
A curvatura da curva oito pode ser montada graficamente com esse comando:
plot2d(kapa(oito, z), [z, -%pi, %pi]);
|
|
|