On Aug. 26, erkenays wrote:
>Hi,There are 6 linear diff. eq. system below that I am dealing with.When I
>solve it, it return false.
>Does anyone know how to solve it? Thank you.
>
The previous solutions was for arbitrary initial conditions
and involved six arbitrary constants, the values of the
unknown functions at x = 0.
If we use your assumptions the results of course
look simpler:
(%i1) display2d:false$
(%i2) eqns:['diff(a(x),x)+b(x)=0,'diff(c(x),x)-b(x)-e(x)+f(x)=0,
'diff(b(x),x)-c(x)-d(x)+a(x)=0,
'diff(e(x),x)-d(x)=0,'diff(d(x),x)+e(x)-f(x)=0,
'diff(f(x),x) - a(x) = 0 ]$
(%i3) (atvalue(b(x),x=0,0), atvalue(e(x),x=0,0),
atvalue(f(x),x=0,0) )$
(%i4) solns : desolve( eqns,[a(x),b(x),c(x),d(x),e(x),f(x)] )$
(%i5) [as,bs,cs,ds,es,fs] : map('rhs, solns)$
(%i6) (asp:diff(as,x),bsp:diff(bs,x),csp:diff(cs,x),
dsp:diff(ds,x),esp:diff(es,x),fsp:diff(fs,x) )$
(%i7) ( subst(x=0,[as,bs,cs,ds,es,fs]),ratsimp(%%) );
(%o7) [a(0),0,c(0),d(0),0,0]
(%i8) ([asp+bs,csp-bs-es+fs,bsp-cs-ds+as,esp-ds,dsp+es-fs,fsp-as],
ratsimp(%%) );
(%o8) [0,0,0,0,0,0]
(%i9) as;
(%o9) (d(0)+c(0)+a(0))/2-(d(0)+c(0)-a(0))*cosh(sqrt(2)*x)/2
(%i10) bs;
(%o10) (d(0)+c(0)-a(0))*sinh(sqrt(2)*x)/sqrt(2)
(%i11) cs;
(%o11)
(2*d(0)+2*c(0)-2*a(0))*cosh(sqrt(2)*x)/3-(2*d(0)-c(0)-2*a(0))*cos(x)/3
(%i12) ds;
(%o12) -(d(0)+c(0)-a(0))*cosh(sqrt(2)*x)/6+(2*d(0)-c(0)-2*a(0))*cos(x)/3
+(d(0)+c(0)+a(0))/2
(%i13) es;
(%o13) -(d(0)+c(0)-a(0))*sinh(sqrt(2)*x)/(6*sqrt(2))
+(2*d(0)-c(0)-2*a(0))*sin(x)/3+(d(0)+c(0)+a(0))*x/2
(%i14) fs;
(%o14) (-d(0)-c(0)+a(0))*sinh(sqrt(2)*x)/(2*sqrt(2))+(d(0)+c(0)+a(0))*x/2
Ted Woollett