On June 28, 2009, Agust?n Valverde Ramos wrote:
----------------------------------------------------------
With this kind of equations, I usually firstly try the conversion to a
system:
(%i1) eq1:A*(-s+1)=2*B*c;
(%o1) (1-s)*A=2*c*B
(%i2) eq2:s^2+c^2=1;
(%o2) s^2+c^2=1
(%i3) solve([eq1,eq2],[s,c]);
(%o3) [[s=1,c=0],[s=-(4*B^2-A^2)/(4*B^2+A^2),c=(4*A*B)/(4*B^2+A^2)]]
Then, the solutions are: arcsin(1)=pi/2 and arcsin(-(4*B^2-A^2)/
(4*B^2+A^2))
-----------------------------------------------
Thanks for the method of enlarging the system of equations
to include the trig identities one would normally hope solve
would use automatically. This is a good strategy, and also
has the advantage that young Maxima users would be encouraged
to remember their trig identities.
The following just adds some solution checks to what you
have done.
-------------------------------------------------------------------
(%i1) display2d:false$
(%i2) eqn : a*(1-sin(x)) -2*b*cos(x) = 0$
(%i3) solve (eqn, x);
(%o3) [sin(x) = -(2*b*cos(x)-a)/a]
(%i4) eq1 : a*(1-s) - 2*b*c = 0$
(%i5) eq2 : c^2 + s^2 -1 = 0$
(%i6) solns : solve ( [eq1, eq2], [s, c] );
(%o6) [[s = 1,c = 0],[s = -(4*b^2-a^2)/(4*b^2+a^2),c = 4*a*b/(4*b^2+a^2)]]
(%i7) solns1 : solns[1];
(%o7) [s = 1, c = 0]
(%i8) [eq1, eq2], solns1, ratsimp;
(%o8) [0 = 0, 0 = 0]
(%i9) solve ( sin(x)=1, x );
solve: using arc-trig functions to get a solution.
Some solutions will be lost.
(%o9) [x = %pi/2]
(%i10) eqn, %, ratsimp;
(%o10) 0 = 0
(%i11) solns2 : solns[2];
(%o11) [s = -(4*b^2-a^2)/(4*b^2+a^2), c = 4*a*b/(4*b^2+a^2)]
(%i12) [eq1, eq2], solns2, ratsimp;
(%o12) [0 = 0, 0 = 0]
(%i13) tan(x) = s/c, solns2, ratsimp;
(%o13) tan(x) = -(4*b^2-a^2)/(4*a*b)
(%i14) solve (%, x), ratsimp;
solve: using arc-trig functions to get a solution.
Some solutions will be lost.
(%o14) [ x = -atan ( (4*b^2-a^2)/(4*a*b) ) ]
(%i15) eqn, x = atan2 ( a^2-4*b^2, 4*a*b ), ratsimp;
(%o15) -(a*sqrt(16*b^4+8*a^2*b^2+a^4)-4*a*b^2-a^3)/(4*b^2+a^2) = 0
(%i16) scanmap ( 'factor, % );
(%o16) 0 = 0
-------------------------------
Ted Woollett